acinclude.m4

   1 dnl $Id$
   2 dnl $Name$
   3
   4 dnl From codeset.m4 (in libcharset):
   5 #serial 2
   6
   7 dnl From Bruno Haible.
   8
   9 AC_DEFUN(jm_LANGINFO_CODESET,
  10 [
  11   AC_CHECK_HEADERS(langinfo.h)
  12   AC_CHECK_FUNCS(nl_langinfo)
  13
  14   AC_CACHE_CHECK([for nl_langinfo and CODESET], jm_cv_langinfo_codeset,
  15     [AC_TRY_LINK([#include <langinfo.h>],
  16       [char* cs = nl_langinfo(CODESET);],
  17       jm_cv_langinfo_codeset=yes,
  18       jm_cv_langinfo_codeset=no)
  19     ])
  20   if test $jm_cv_langinfo_codeset = yes; then
  21     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
  22       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
  23   fi
  24 ])
  25
  26 dnl From glibc21.m4 (in libcharset):
  27 #serial 2
  28
  29 # Test for the GNU C Library, version 2.1 or newer.
  30 # From Bruno Haible.
  31
  32 AC_DEFUN(jm_GLIBC21,
  33   [
  34     AC_CACHE_CHECK(whether we are using the GNU C Library 2.1 or newer,
  35       ac_cv_gnu_library_2_1,
  36       [AC_EGREP_CPP([Lucky GNU user],
  37         [
  38 #include <features.h>
  39 #ifdef __GNU_LIBRARY__
  40  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 1) || (__GLIBC__ > 2)
  41   Lucky GNU user
  42  #endif
  43 #endif
  44         ],
  45         ac_cv_gnu_library_2_1=yes,
  46         ac_cv_gnu_library_2_1=no)
  47       ]
  48     )
  49     AC_SUBST(GLIBC21)
  50     GLIBC21="$ac_cv_gnu_library_2_1"
  51   ]
  52 )
  53
  54 dnl Own functions
  55 dnl gedcom_GLIBC_ICONV()
  56 dnl Checks whether iconv is coming from glibc, defines USE_GLIBC_ICONV if so
  57 dnl The variable $is_glibc_iconv contains yes or no
  58 AC_DEFUN(gedcom_GLIBC22_ICONV, [
  59   AC_CACHE_CHECK(for the GNU C Library 2.2 iconv implementation, is_glibc22_iconv, [
  60     AC_EGREP_CPP(yes,
  61     [
  62 #include <iconv.h>
  63 #ifdef __GLIBC__
  64  #if (__GLIBC__ == 2 && __GLIBC_MINOR__ >= 2) || (__GLIBC__ > 2)
  65 yes
  66  #endif
  67 #endif
  68     ], is_glibc22_iconv=yes, is_glibc22_iconv=no)
  69   ])
  70   if test "$is_glibc22_iconv" = yes; then
  71     AC_DEFINE(USE_GLIBC_ICONV,1,
  72       [Define if the GNU implementation of iconv in glibc is used])
  73   fi
  74 ])
  75
  76 dnl gedcom_ICONV_HAS_CONV()
  77 dnl Checks whether iconv has support to convert $1 to $2
  78 dnl The variable $iconv_has_conv contains yes or no afterwards
  79 dnl (overwritten on subsequent calls)
  80 AC_DEFUN(gedcom_ICONV_HAS_CONV, [
  81   my_save_LIBS="$LIBS"
  82   LIBS="$LIBS $LIBICONV"
  83   AC_TRY_RUN([
  84 #include <iconv.h>
  85 int main() {
  86   iconv_t cd = iconv_open("$2","$1");
  87   return (cd == (iconv_t)-1);
  88 }
  89     ],
  90     iconv_has_conv=yes,
  91     iconv_has_conv=no,
  92     iconv_has_conv=no)
  93     LIBS="$my_save_LIBS"
  94   ])
  95 ])
  96
  97 dnl gedcom_SANE_ICONV()
  98 dnl Checks whether the iconv implementation has the basic functionality
  99 dnl that we need
 100 dnl The variable $is_iconv_sane contains yes or no
 101 AC_DEFUN(gedcom_SANE_ICONV, [
 102   AC_CACHE_CHECK(whether iconv has the needed functionality, is_iconv_sane, [
 103     is_iconv_sane=yes
 104     gedcom_ICONV_HAS_CONV(ASCII, UTF-8)
 105     if test "$iconv_has_conv" = "no"; then
 106       is_iconv_sane=no
 107     else
 108       gedcom_ICONV_HAS_CONV(UCS-2LE, UTF-8)
 109       if test "$iconv_has_conv" = "no"; then
 110         is_iconv_sane=no
 111       else
 112         gedcom_ICONV_HAS_CONV(UCS-2BE, UTF-8)
 113         if test "$iconv_has_conv" = "no"; then
 114           is_iconv_sane=no
 115         fi
 116       fi
 117     fi
 118   ])
 119 ])
 120
 121 dnl gedcom_LIBICONV_HAS_ANSEL()
 122 dnl Checks whether libiconv has ANSEL support
 123 dnl The variable $is_ansel_supported contains yes or no
 124 AC_DEFUN(gedcom_LIBICONV_HAS_ANSEL, [
 125   AC_CACHE_CHECK(for ANSEL support in libiconv, is_ansel_supported, [
 126     is_ansel_supported=no
 127     gedcom_ICONV_HAS_CONV(ANSEL, UTF-8)
 128     if test "$iconv_has_conv" = yes; then
 129       is_ansel_supported=yes
 130     fi
 131   ])
 132 ])
 133
 134 dnl gedcom_SYS_NEWLINE()
 135 dnl Checks how newline is written on the system
 136 dnl SYS_NEWLINE is set to one of the following:
 137 dnl END_CR, END_LF, END_CR_LF, END_LF_CR
 138 AC_DEFUN(gedcom_SYS_NEWLINE, [
 139   AC_CACHE_CHECK(how to represent newline, ac_cv_system_newline, [
 140     echo > newlinetest
 141     AC_TRY_RUN([
 142 #include <sys/types.h>
 143 #include <sys/stat.h>
 144 #include <fcntl.h>
 145 #include <stdio.h>
 146 int main() {
 147   char buffer[11];
 148   int i, fd;
 149   FILE* f;
 150   for (i=0; i<10; i++) { buffer[i] = '\0'; }
 151   fd = open("newlinetest", O_RDONLY);
 152   if (fd == -1) return 1;
 153   read(fd, buffer, 10);
 154   close(fd);
 155   f = fopen("newlinetest", "w");
 156   if (!f) return 1;
 157   i = 0;
 158   while (buffer[i] != '\0') { fprintf(f, "%02x", buffer[i++]); }
 159   fclose(f);
 160   return 0;
 161 }
 162     ],
 163     [system_newline_output=`cat newlinetest`
 164      case "$system_newline_output" in
 165        0a0d) ac_cv_system_newline="\"\x0A\x0D\"" ;;
 166        0d0a) ac_cv_system_newline="\"\x0D\x0A\"" ;;
 167        0a)   ac_cv_system_newline="\"\x0A\"" ;;
 168        0d)   ac_cv_system_newline="\"\x0D\"" ;;
 169        *)    ac_cv_system_newline="\"\x0A\"" ;;
 170      esac],
 171     ac_cv_system_newline="\"\x0A\"",
 172     ac_cv_system_newline="\"\x0A\"")
 173     rm -f newlinetest
 174   ])
 175   AC_DEFINE_UNQUOTED(SYS_NEWLINE,$ac_cv_system_newline,
 176     [The representation of newline in text files in the system])
 177 ])